perintah ShaderLab: Login

GrabPass adalah perintah yang menciptakan jenis Pass khusus yang mengambil isi dari penyangga bingkai menjadi tekstur. Tekstur ini dapat digunakan di Pass berikutnya untuk melakukan efek berbasis gambar canggih.

Perintah ini dapat secara signifikan meningkatkan waktu bingkai CPU dan GPU. Anda umumnya harus menghindari menggunakan perintah ini selain untuk prototyping cepat, dan mencoba untuk mencapai efek Anda dengan cara lain. Jika Anda menggunakan perintah ini, cobalah untuk mengurangi jumlah operasi pengambilan layar sebanyak mungkin; baik dengan mengurangi penggunaan perintah ini, atau dengan menggunakan tanda tangan yang mengambil layar ke tekstur bernama jika berlaku.

Kompatibilitas pipa Render

Feature name	Built-in Render PipelineA series of operations that take the contents of a Scene, and displays them on a screen. Unity lets you choose from pre-built render pipelines, or write your own. More info See in Glossary	Universal Render Pipeline (URP)	High Definition Render Pipeline (HDRP)	Custom SRP
GrabPass	Yes	No	No	No

Usage

Gunakan perintah ini di blok SubShader.

GrabPass hanya bekerja pada penyangga bingkai. Anda tidak dapat menggunakan perintah ini untuk mengambil isi dari target render lainnya, depth bufferSebuah toko memori yang memegang kedalaman nilai z setiap pixel dalam gambar, di mana nilai z adalah kedalaman untuk setiap piksel yang diberikan dari pesawat proyeksi. More info
Lihat di Glossary, dan sebagainya.

Perhatikan bahwa dua tanda tangan yang berbeda memiliki fungsi yang berbeda, dan implikasi kinerja yang berbeda. Menggunakan tekstur bernama dapat mengakibatkan operasi pengambilan layar yang lebih sedikit, yang dapat mengurangi dampak dari perintah intensif sumber daya ini.

Signature	Function
GrabPass { }	Ambil konten penyangga bingkai menjadi tekstur yang dapat Anda gunakan di Passes berikutnya di SubShader yang sama. Reference tekstur menggunakan nama _GrabTexture. Ketika Anda menggunakan tanda tangan ini, Unity mengambil layar setiap kali itu render batch yang berisi perintah ini. Ini berarti bahwa Unity dapat mengambil layar beberapa kali per bingkai: sekali untuk setiap batch.
GrabPass { "ExampleTextureName" }	Ambil konten penyangga bingkai menjadi tekstur yang dapat Anda akses di Passes berikutnya dalam bingkai yang sama, di beberapa SubShaders. Ketika Anda menggunakan tanda tangan ini, Unity mengambil layar pertama dalam bingkai yang renders batch yang berisi perintah ini dengan nama tekstur yang diberikan.

Examples

Contoh ini untuk Pipeline Render Built-in menunjukkan menggunakan GrabPass untuk mengalihkan warna target render. Perhatikan bahwa ini bukan cara yang efisien untuk mencapai efek ini, dan dimaksudkan hanya untuk menunjukkan penggunaan GrabPass; efek yang sama dapat dicapai lebih efisien menggunakan mode campuran terbalik.

Shader "GrabPassInvert"
{
    SubShader
    {
        // Draw after all opaque geometry
        Tags { "Queue" = "Transparent" }

        // Grab the screen behind the object into _BackgroundTexture
        GrabPass
        {
            "_BackgroundTexture"
        }

        // Render the object with the texture generated above, and invert the colors
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            struct v2f
            {
                float4 grabPos : TEXCOORD0;
                float4 pos : SV_POSITION;
            };

            v2f vert(appdata_base v) {
                v2f o;
                // use UnityObjectToClipPos from UnityCG.cginc to calculate 
                // the clip-space of the vertex
                o.pos = UnityObjectToClipPos(v.vertex);

                // use ComputeGrabScreenPos function from UnityCG.cginc
                // to get the correct texture coordinate
                o.grabPos = ComputeGrabScreenPos(o.pos);
                return o;
            }

            sampler2D _BackgroundTexture;

            half4 frag(v2f i) : SV_Target
            {
                half4 bgcolor = tex2Dproj(_BackgroundTexture, i.grabPos);
                return 1 - bgcolor;
            }
            ENDCG
        }

    }
}